批次檔內的時間不會改變

bat批次檔

shadowpeople 2016-12-09 21:54:00 ‧ 5845 瀏覽

批次檔範例如下

for /L %%I in (0 1 430) do (
	echo %DATE% %TIME%
	echo %date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%:%time:~3,2%
	timeout /t 30
)

原本的本意是想取得當下的系統時間
但是執行後才發現，顯示出來的時間一直停留在剛執行批次檔的時間
請問有人可以幫忙解惑嗎？

中華民國的居民 iT邦新手 5 級 ‧ 2016-12-09 22:17:26 檢舉

for /L %%I in (0 1 430) do (
echo %DATE% %TIME%
echo %date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%:%time:~3,2%
timeout /t 10
C:\Users\goodman\Desktop\test.bat
)

中華民國的居民 iT邦新手 5 級 ‧ 2016-12-09 22:18:40 檢舉

最後一行,是故意執行自己,算是另類的遞回。但不是真正的遞回喔!,因為沒有傳值。

中華民國的居民 iT邦新手 5 級 ‧ 2016-12-09 22:21:57 檢舉

echo off
for /L %%I in (0 1 430) do (
echo %DATE% %TIME%
echo %date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%:%time:~3,2%
timeout /t 10
cls
C:\Users\goodman\Desktop\test.bat
)
rem 畫面太亂了,自己多加了cls,還有,30秒等太久,我改成10秒,要怎麼改看各自方便

登入發表討論

直播研討會

{{ item.channelVendor }} {{ item.webinarstarted }} |

直播中

3 個回答

蟹老闆

iT邦大師 1 級 ‧ 2016-12-09 23:53:32

最佳解答

請參考

@Echo off
SetLocal ENABLEDELAYEDEXPANSION
for /L %%I in (0 1 430) do (
echo !DATE! !TIME!
echo !date:~0,4!-!date:~5,2!-!date:~8,2! !time:~0,2!:!time:~3,2!
timeout /t 30
)

回應 3
分享
檢舉

海綿寶寶 iT邦大神 1 級 ‧ 2016-12-11 10:53:33 檢舉

他們兩位的帳號都姓 Huang
您知道嗎
不知道就安靜
不然就回去再看一次

蟹老闆 iT邦大師 1 級 ‧ 2016-12-12 13:42:19 檢舉

海線寶寶真細心,很多時候都注意到了小細節

中華民國的居民 iT邦新手 5 級 ‧ 2017-04-30 15:30:34 檢舉

我好久沒上線了,請問哪裡可以看到我的公開資料(為什麼會知道我的姓氏呢)? 你們是IT幫幫忙的admin或站務人員嗎? 下次上線可能很久了。再會。

登入發表回應

wwx

iT邦好手 1 級 ‧ 2016-12-10 13:19:51

請試以下批次檔內容~

@echo off

for /L %%I in (0 1 430) do (
@call :GetDateTime %%I
timeout /t 30
)

:ExitBat
goto :EOF

:GetDateTime
echo I=(%1)
echo %DATE% %TIME%
echo %date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%:%time:~3,2%
goto :EOF

回應 1
分享
檢舉

wwx iT邦好手 1 級 ‧ 2016-12-25 10:20:03 檢舉

提示: 用的都是原問的code,也不用把%改成!

登入發表回應

eigen

iT邦新手 1 級 ‧ 2016-12-11 15:46:04

:Function_date
For /f "tokens=1-4 delims=/ " %%a in ('date /t') do (set yy=%%a& set mm=%%b& set dd=%%c& set ww=%%d)
set mmm=1%mm% & set /a mmm-=100
set ddd=1%mm% & set /a ddd-=100
set /a today_cnt=(%yy%-%YearStart%)*365+%mmm%*30+%ddd%
:Function_date_end

:Function_time
for /f "tokens=2-5 delims=:. " %%a in ('echo. ^|time') do (set hhh=%%a& set min=%%b& set sec=%%c& set cent=%%d)
if %hhh% LSS 10 (set hhh=0%hhh%)
:Function_time_end

set Destination=_%yy%_%mm%%dd%_%hhh%%min%_%sec%%cent%

D:\>set Destination=_2016_1211_1544_5047