DOS HELP 指令說明產生器

指令 dos

蟹老闆 2014-07-22 18:36:58 ‧ 2868 瀏覽

分享至

將 HELP 說明指令所提到的指令匯出成一個HTML檔這樣比較方便閱讀,有幾個指令不知道為什麼無法匯出
點指令可以查看詳細說明,其它應該沒什麼好說明的直接看結果比較實在

@Echo Off
Cls
Md "%SystemRoot%\MdTest" 2>nul&&Rd "%SystemRoot%\MdTest" >nul 2>nul||(Echo.&Echo.&Echo 請使用右鍵以系統管理員身分執行&Echo.&Echo.&Echo.&Echo.&Pause&Exit)
Set FileName=Command
(Echo ^<^!DOCTYPE html PUBLIC ^"-^/^/W3C^/^/DTD XHTML 1.0 Transitional^/^/EN^" ^"http:^/^/www.w3.org^/TR^/xhtml1^/DTD^/xhtml1-transitional.dtd^"^>
Echo ^<html xmlns^=^"http:^/^/www.w3.org^/1999^/xhtml^"^>
Echo ^<head^>
Echo ^<meta http-equiv^=^"Content-Type^" content^=^"text^/html; charset^=Big5^" ^/^>
Echo ^<title^>Windows 基本指令說明^<^/title^>
Echo ^<^/head^>
Echo ^<body^>
Echo ^<div align^=^"center^"^>
Echo   ^<h1^>^<a name^=^"Top^"^>Windows 基本指令說明手冊^<^/a^>^<^/h1^>
Echo ^<^/div^>
Echo ^<table width^=^"800^" border^=^"0^" align^=^"center^" cellpadding^=^"1^" cellspacing^=^"1^"^>
Echo   ^<caption^>^<strong^>命令列表^<^/strong^>^<^/caption^>
Echo   ^<tr^>
Echo     ^<td width^=^"100^"^>^<div align^=^"center^"^>指令^<^/div^>^<^/td^>
Echo     ^<td width^=^"690^"^>^<div align^=^"center^"^>簡介^<^/div^>^<^/td^>
Echo   ^<^/tr^>
::-----------------------------------
For /f "tokens=1,* delims= " %%I in ('Help^|Findstr /b [A-Z]') Do ( 
Echo   ^<tr^>
Echo     ^<td width^=^"100^" bgcolor^=^"#66CCFF^"^>^<strong^>^<a href^=^"^#%%I^"^>%%I^<^/a^>^<^/strong^>^<^/td^>
Echo     ^<td width^=^"690^" bgcolor^=^"#99FF33^"^>%%J^<^/td^>
Echo   ^<^/tr^>
)
::-----------------------------------
Echo ^<^/table^>
Echo ^<hr ^/^>
Echo ^<div align^=^"center^"^>^<strong^>詳細說明^<^/strong^>^<^/div^>
Echo ^<table width^=^"800^" border^=^"0^" align^=^"center^" cellpadding^=^"0^" cellspacing^=^"0^"^>) >"%~dp0%FileName%.html"
::-----------------------------------
For /f "tokens=1* delims= " %%I in ('Help^|Findstr /b [A-Z]') Do (
::-----------------------------------
Echo   ^<tr^> >>"%~dp0%FileName%.html"
Echo     ^<td^>^<div align^=^"left^"^>^<fieldset^>^<legend^>^<a name^=^"%%I^"^>%%I^<^/a^>^<^/legend^> >>"%~dp0%FileName%.html"
Echo ^<textarea name^=^"textarea^" id^=^"%%I^" cols^=^"95^" rows^=^"5^"^>  >>"%~dp0%FileName%.html"
REM =======例外處理=======
IF %%I EQU REM REM /?>>"%~dp0%FileName%.html"
IF %%I EQU FOR FOR /?>>"%~dp0%FileName%.html"
IF %%I EQU IF IF /?>>"%~dp0%FileName%.html"
IF %%I EQU GRAFTABL Echo 指令:%%I 不支援輸出說明請自行在 DOS 視窗中輸入 %%I /? 來查詢使用方法. >>"%~dp0%FileName%.html"
IF %%I EQU SC Echo 請按任意鍵繼續..........
REM =======例外處理=======
%%I /? >>"%~dp0%FileName%.html"
Echo ^<^/textarea^> >>"%~dp0%FileName%.html"
Echo ^<^/fieldset^> ^<^/div^> >>"%~dp0%FileName%.html"
Echo     ^<div align^=^"right^"^>^<a href^=^"#Top^"^>回頂端^<^/a^>^<^/div^>^<^/td^> >>"%~dp0%FileName%.html"
Echo   ^<^/tr^> >>"%~dp0%FileName%.html"
)
(Echo ^<^/table^>
Echo ^<Div align^=^"right^"^>Design:^<a href^=^"dreamer^@mail.dingerbs.com^"^>Dreamer^<^/a^>^<^/div^>
Echo ^<^/body^>
Echo ^<^/html^> 
)  >>"%~dp0%FileName%.html"
START "開啟說明" "%~dp0%FileName%.html"

將上面的指令碼存成.BAT然後執行,執行完畢會直接開啟該HTML檔,在該.BAT檔相同目錄下也會產生一個HTML檔供留存。