方法一、表格加上陣列公式：

1. 先將主表與調查表，分別套用「格式化為表格」功能。
2. 再於F2寫下=IF(SUM((主表[公司]=[@公司])*(主表[商品]=[@商品])*1),"無異動","新增至主表")，按下CTRL+SHIFT+ENTER

方法二、輔助欄位加上MATCH函數：

1. 在主表加上輔助欄位公司+商品，公式為=A2&"-"&B2
2. 在G2儲存格寫下=IF(ISNUMBER(MATCH(E2&"-"&F2,$C$2:$C$8,0)),"無異動","新增至主表")按下ENTER即可。

方法三、表格加上COUNTIFS公式:

1. 先將主表與調查表，分別套用「格式化為表格」功能。
2. 再於F2寫下=IF(COUNTIFS(主表[公司],[@公司],主表[商品],[@商品]),"無異動","新增至主表")，按下ENTER即可。

我這邊嘗試使用ISNUMBER + SEARCH + IF的方式來解決你的問題

結果圖:

Script:

=IF(
     AND((D5=A5),ISNUMBER(SEARCH(E5,B:B))),"無異動","新增至主表"
)

解析:

需要變更的地方，E列代表新的商品，B列代表舊的產品
所以把E加上指定行，去遍歷(B:B)比對是否有過這個值

寫到這裡我卡點了，問題點:

怎麼在使用Search發現有值的情況下，又取得它是第幾行資料
這樣才能比對公司一樣又包含商品

這邊我明天在想想怎麼解決...(應該用Indexof可以解決)
以上邏輯先提供給你

解決方式:

新增一個"商品編號列"，裡面值由A列跟B列字串相加(如圖-1)

=CONCATENATE(A3, "-",B3)

接著把之前的script改成:

=IF(
	(CONCATENATE(E2, "-",F2) = "-"),"",
	IF(
		ISNUMBER(SEARCH(CONCATENATE(E2, "-",F2),C:C)),"無異動","新增至主表"
    )
)

• 其中欄位行號要自己下拉變化
• 前一個IF為了防新商品的公司跟商品都是空白字串情況
• 第二個IF判斷邏輯:"公司+商品字串"是否包含在"商品編號"裡面

以下參考連結:

【Excel-IF使用三個條件判斷式(AND,OR,＊運算子)】
配合Search就可以
【 檢查儲存格是否包含文字 (不區分大小寫) 】

C1=A1&B1 (C2..C7 公式由 C11 複製)
F1=D1&E1 (F2..F6 公式由 F1 複製)
G1=IF(ISNA(VLOOKUP(F1,$C:$C,1,FALSE)),"新增至主表","無異動")

(G2..G6 公式由 G1 複製)