iT邦幫忙

0

Excel 重複資料取日期最大三筆到其他欄位!!!

各位IT前輩,有一個Excel問題想請教~
如下圖,A欄有很多重複值,以A欄2475-leads值來呈現結果,想把E,F欄,最後三筆資料,分別塞到K,L,M,N,O,P欄位,抓日期最大值前三筆...
因為之前的邏輯差在一個函數關係,所以改成這樣的邏輯,麻煩前輩指點...
https://ithelp.ithome.com.tw/upload/images/20180511/20089833Zjp6Je0AgG.jpg

看更多先前的討論...收起先前的討論...
pcw iT邦研究生 5 級 ‧ 2018-05-11 17:12:27 檢舉
給定某個A欄的值,在F欄位會有重複的值嗎?
小哈 iT邦新手 4 級 ‧ 2018-05-11 17:16:42 檢舉
pcw前輩,A欄同一筆會有些重複的日期,不過日期後面有接時間例如:2018/3/5 03:21:33 AM
zxc170170 iT邦新手 5 級 ‧ 2018-05-11 17:17:51 檢舉
你是說條件1: A欄有相同的值[2475-leads],條件2:找出符合條件1並且在F欄中日期前三天,自動判斷到K~P欄?
小哈 iT邦新手 4 級 ‧ 2018-05-11 17:24:55 檢舉
1.以A欄相同的值,去自動判斷抓F欄最新日期的三筆資料到K~P欄,E欄也是一樣的原理~麻煩各位前輩了...
pcw iT邦研究生 5 級 ‧ 2018-05-11 17:27:31 檢舉
@哈利
給定某個A欄位的值,F欄位的(日期+時間)會不會有重複的值?
小哈 iT邦新手 4 級 ‧ 2018-05-11 17:30:00 檢舉
pcw前輩~F欄,如果是日期加上時間,就不會有重複的值了~~

1 個回答

0
pcw
iT邦研究生 5 級 ‧ 2018-05-11 17:43:02
最佳解答

用陣列公式

在K2

  1. 寫下=LARGE(IF((工作表1!$A$2:$A$35=$J2),工作表1!$C$2:$C$35,""),1)
  2. 按下Ctrl + Shift + Enter

在L2

  1. 寫下=LARGE(IF((工作表1!$A$2:$A$35=$J2),工作表1!$C$2:$C$35,""),2)
  2. 按下Ctrl + Shift + Enter

在M2

  1. 寫下=LARGE(IF((工作表1!$A$2:$A$35=$J2),工作表1!$C$2:$C$35,""),3)
  2. 按下Ctrl + Shift + Enter

在N2

  1. 寫下=INDEX(工作表1!$B$2:$B$35,MIN(IF((工作表1!$A$2:$A$35=$J2)*(工作表1!$C$2:$C$35=$K2),ROW(INDIRECT("1:"&ROWS(工作表1!$A$2:$C$35))),"")))
  2. 按下Ctrl + Shift + Enter

在O2

  1. 寫下=INDEX(工作表1!$B$2:$B$35,MIN(IF((工作表1!$A$2:$A$35=$J2)*(工作表1!$C$2:$C$35=$L2),ROW(INDIRECT("1:"&ROWS(工作表1!$A$2:$C$35))),"")))
  2. 按下Ctrl + Shift + Enter

在P2

  1. 寫下=INDEX(工作表1!$B$2:$B$35,MIN(IF((工作表1!$A$2:$A$35=$J2)*(工作表1!$C$2:$C$35=$M2),ROW(INDIRECT("1:"&ROWS(工作表1!$A$2:$C$35))),"")))
  2. 按下Ctrl + Shift + Enter

選取K2:P2,用填滿控點往下拉

結果

結果

小哈 iT邦新手 4 級 ‧ 2018-05-11 17:54:47 檢舉

感謝前輩指點,我在試試看/images/emoticon/emoticon02.gif

小哈 iT邦新手 4 級 ‧ 2018-05-15 09:50:32 檢舉

感謝pcw前輩指點,目前完成測試~太感謝了/images/emoticon/emoticon08.gif

我要發表回答

立即登入回答