excel求神人~資料重複及彙整

excel

blacksmile 2025-02-05 12:23:57 ‧ 1561 瀏覽

分享至

excel求神人~
圖一的報表內有重複的訂單編號，但品項及金額不同，想把重複的訂單編號篩選保留一筆，但品項中須將不同品項彙整在同一個品項欄位內，並將金額加總(如圖二)；
或是將品項變成在同一筆訂單後面增加品項欄位及金額欄位(如圖三)；
求神人詳解excel公式，跪求，感恩

看更多先前的討論...收起先前的討論...

froce iT邦大師 1 級 ‧ 2025-02-05 12:42:04 檢舉

公式很難做到，但...
powerquery可以做到2

marguerite iT邦新手 4 級 ‧ 2025-02-05 16:02:26 檢舉

寫VBA應該可以做到

froce iT邦大師 1 級 ‧ 2025-02-05 16:16:40 檢舉

給樓上的:
寫VBA不會比寫powerquery簡單，powerquery這個應該可以在5步內完成。
powerquery你把它當excel裡面的資料庫語言來用就行了。
這個其實介面拉一拉之後group by然後改品項那欄的join而已。

只是很難教學...

尼克 iT邦大師 1 級 ‧ 2025-02-05 16:56:20 檢舉

大推 powerquery

登入發表討論

直播研討會

{{ item.channelVendor }} {{ item.webinarstarted }} |

直播中

1 個回答

ccenjor

iT邦大師 8 級 ‧ 2025-02-05 20:51:01

模式1解法：
G2:
=IF(COUNTIF($A$1:A2,A2)=1,A2,"")
H2:
=TEXTJOIN(",",,IF((G2<>"") * (A$2:A$8=G2),B$2:B$8,""))
(若2021/2024/365版本)公式可改為
=TEXTJOIN(",",,FILTER(B$2:B$8,A$2:A$8=G2,""))
I2:
=IF(G2<>"",SUM(IF((G2<>"") * (A$2:A$8=G2),C$2:C$8,"")),"")
(若2021/2024/365版本)公式可改為
=SUM(FILTER(C$2:C$8,A$2:A$8=G2,0))
J2:
=IF(G2<>"",VLOOKUP(G2,A$2:E$8,4,0),"")
K2:
=IF(G2<>"",VLOOKUP(G2,A$2:E$8,5,0),"")
將G2:K2框選起來，複製公式到G2:K8。

模式2解法：
M2:
=IF(COUNTIF($A$1:A2,A2)=1,A2,"")
將公式複製到M3:M8
N2:
=IF($M$2<>"",IFERROR(INDEX($B$1:$B$8,SMALL(IF($A$2:$A$8=$M2,ROW($A$2:$A$8),""),COLUMN()-13)),""),"")
將公式複製到N2:Q8
(若2021/2024/365版本)公式可改為
=TRANSPOSE(FILTER($B$2:$B$8,$A$2:$A$8=M2,""))
R2:
=IF($M$2<>"",IFERROR(INDEX($C$1:$C$8,SMALL(IF($A$2:$A$8=$M2,ROW($A$2:$A$8),""),COLUMN()-17)),""),"")
將公式複製到R2:T8
(若2021/2024/365版本)公式可改為
=TRANSPOSE(FILTER($C$2:$C$8,$A$2:$A$8=M2,""))
S2:
=IF(M2<>"",VLOOKUP(G2,$A$2:$E$8,4,0),"")
將公式複製到S3:S8
T2:
=IF(M2<>"",VLOOKUP(M2,$A$2:$E$8,5,0),"")
將公式複製到T3:T8