沒有測試、無法測試
希望可以派上用場

@echo off
setlocal enableDelayedExpansion

set "regPath=HKEY_CURRENT_USER\SOFTWARE\Microsoft\Office\15.0\Outlook\Profiles\Outlook"
set find_ValueName=001e6601
set find_Type=REG_SZ
set newPort=123

set cmdstr=reg query "%regPath%" /f "%find_ValueName%" /e /v  /t "%find_Type%" /s

::畫面右邊某一個值
::reg query regPath /v 值的名稱

::regPath (預設值)
::reg query regPath /ve

::畫面左邊「子資料夾」 or 畫面右邊「值的名稱」 or 畫面右邊「值的值」
::reg query regPath /f 部份符合字串
::reg query regPath /f 完全符合字串 /e

:: /c 區分大小寫
:: /t 值的type
:: /s 尋找各層


::畫面左邊子資料夾
::reg query regPath /f 部份符合字串 /k

::畫面左邊所有的子資料夾
::reg query regPath /f * /k

::畫面右邊「值的名稱」
::reg query regPath /f 部份符合字串 /v

::畫面右邊「值的值」
::reg query regPath /f 部份符合字串 /d

for /f "delims=" %%a in ('%cmdstr%') do (
    set line=%%a

    rem 先顯示regKey的路徑
    if "!line:~0,5!" == "HKEY_" (
         echo keyPath=!line!
         set keyPath=!line!
    )

    rem 再顯示找到的值「名稱」、「型別」、「值」
    if "!line:~0,4!" == "    " (

        rem 2022/3/5 update
        rem 這行是舊版 for /f "tokens=1-3" %%f in ("!line!") do (
        
        rem 下面是新版。值的「內容」可以含有空格了。
        rem 但是，值的「名稱」仍然不能含有空格。
        for /f "tokens=1,2*" %%f in ("!line!") do (
            echo ValueName=%%f
            echo ValueType=%%g
            echo Value=%%h

            rem 如果正確的話，移除前面的echo
            echo reg add "!keyPath!" /v "%%f" /t %%g /d "%newPort%" /f
        )
    )
    pause
)