DAY 24 - 荷蘭拍賣

16th鐵人賽

anzhe

2024-10-08 23:51:34

46 瀏覽

分享至

荷蘭拍賣

荷蘭拍賣（Dutch Auction）是一種特殊的拍賣形式，亦稱為「減價拍賣」，它是指拍賣標的的競價由高到低依次遞減直到第一個競買人應價（達到或超過底價）時擊槌成交的一種拍賣。
在幣圈，許多NFT透過荷蘭拍賣發售，其中包括 Azuki 和 World of Women，其中 Azuki 透過荷蘭拍賣籌集了超過 8000 枚 ETH。
專案方非常喜歡這種拍賣形式，主要有兩個原因：

荷蘭拍賣的價格由最高慢慢下降，能讓專案方獲得最大的收入。
拍賣持續較長（通常6小時以上），可以避免 gas war。

DutchAuction合約

程式碼基於 Azuki 的程式碼簡化而成。DucthAuction 合約繼承了先前介紹的 ERC721 和 Ownable 合約：

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

import "@openzeppelin/contracts/access/Ownable.sol";
import "https://github.com/AmazingAng/WTF-Solidity/blob/main/34_ERC721/ERC721.sol";

contract DutchAuction is Ownable, ERC721 {
    uint256 public constant COLLECTOIN_SIZE = 10000; // NFT 總數
    uint256 public constant AUCTION_START_PRICE = 1 ether; // 起拍價（最高價）
    uint256 public constant AUCTION_END_PRICE = 0.1 ether; // 結束價(最低價/地板價)
    uint256 public constant AUCTION_TIME = 10 minutes; // 拍賣時間，為了測試方便設為10分鐘
    uint256 public constant AUCTION_DROP_INTERVAL = 1 minutes; // 每過多久時間，價格衰減一次
    uint256 public constant AUCTION_DROP_PER_STEP =
        (AUCTION_START_PRICE - AUCTION_END_PRICE) /
        (AUCTION_TIME / AUCTION_DROP_INTERVAL); // 每次價格衰減步長
    
    uint256 public auctionStartTime; // 拍賣開始時間戳
    string private _baseTokenURI;   // metadata URI
    uint256[] private _allTokens; // 記錄所有存在的 tokenId

DutchAuction 狀態變數

合約中總共有 9 個狀態變數，其中有 6 個和拍賣相關：

COLLECTOIN_SIZE：NFT 總量。
AUCTION_START_PRICE：荷蘭拍賣起拍價，也是最高價。
AUCTION_END_PRICE：荷蘭拍賣結束價，也是最低價/地板價。
AUCTION_TIME：拍賣持續時長。
AUCTION_DROP_INTERVAL：每過多久時間，價格衰減一次。
auctionStartTime：拍賣起始時間（區塊鏈時間戳，block.timestamp）。

DutchAuction 函數

荷蘭拍賣合約中共有 9 個函數，與 ERC721 相關的函數我們這裡不再重複介紹，只介紹和拍賣相關的函數。

設定拍賣起始時間：我們在建構子中會宣告當前區塊時間為起始時間，專案方也可以透過 setAuctionStartTime() 函數來調整：

constructor() ERC721("WTF Dutch Auctoin", "WTF Dutch Auctoin") {
    auctionStartTime = block.timestamp;
}

// auctionStartTime setter 函數，onlyOwner
function setAuctionStartTime(uint32 timestamp) external onlyOwner {
    auctionStartTime = timestamp;
}

取得拍賣即時價格：getAuctionPrice() 函數透過當前區塊時間以及拍賣相關的狀態變數來計算即時拍賣價格。

當 block.timestamp 小於起始時間，價格為最高價 AUCTION_START_PRICE
當 block.timestamp 大於結束時間，價格為最低價 AUCTION_END_PRICE
當 block.timestamp 處於兩者之間時，則計算出目前的衰減價格

    // 取得拍賣即時價格
    function getAuctionPrice()
        public
        view
        returns (uint256)
    {
        if (block.timestamp < auctionStartTime) {
        return AUCTION_START_PRICE;
        }else if (block.timestamp - auctionStartTime >= AUCTION_TIME) {
        return AUCTION_END_PRICE;
        } else {
        uint256 steps = (block.timestamp - auctionStartTime) /
            AUCTION_DROP_INTERVAL;
        return AUCTION_START_PRICE - (steps * AUCTION_DROP_PER_STEP);
        }
    }

使用者拍賣並鑄造 NFT：使用者透過呼叫 auctionMint() 函數，支付 ETH 參加荷蘭拍賣並鑄造 NFT。

此函數首先檢查拍賣是否開始/鑄造是否超出 NFT 總量。接著，合約透過 getAuctionPrice() 和鑄造數量計算拍賣成本，並檢查使用者支付的 ETH 是否足夠：如果足夠，則將 NFT 鑄造給使用者，並退回超額的 ETH；反之，則回退交易。

    // 拍賣 mint 函數
function auctionMint(uint256 quantity) external payable{
    uint256 _saleStartTime = uint256(auctionStartTime); // 建立 local 變數，減少 gas 花費
    require(
    _saleStartTime != 0 && block.timestamp >= _saleStartTime,
    "sale has not started yet"
    ); // 檢查是否設定起拍時間，拍賣是否開始
    require(
    totalSupply() + quantity <= COLLECTOIN_SIZE,
    "not enough remaining reserved for auction to support desired mint amount"
    ); // 檢查是否超過 NFT 上限

    uint256 totalCost = getAuctionPrice() * quantity; // 計算 mint 成本
    require(msg.value >= totalCost, "Need to send more ETH."); // 檢查使用者是否支付足夠 ETH

    // Mint NFT
    for(uint256 i = 0; i < quantity; i++) {
        uint256 mintIndex = totalSupply();
        _mint(msg.sender, mintIndex);
        _addTokenToAllTokensEnumeration(mintIndex);
    }
    // 多餘 ETH 退款
    if (msg.value > totalCost) {
        payable(msg.sender).transfer(msg.value - totalCost); // 注意這裡是否有重入的風險
    }
}

專案方取出籌集的 ETH：專案方可以透過 withdrawMoney() 函數提走拍賣會籌集的 ETH

    // 提款函數，onlyOwner
function withdrawMoney() external onlyOwner {
    (bool success, ) = msg.sender.call{value: address(this).balance}(""); // call 函數呼叫
    require(success, "Transfer failed.");
}