你可以用 MsgBox 先把檔案字串印出來,
確認看看名稱有沒有錯誤,
先確定是哪個步驟的問題.

Sub ExtractAllFiles()
    Dim File As String
    Dim ShellStr
    
    File = Dir("C:\test\*.tar")

    Do Until File = ""
        DoEvents
        ShellStr = "C:\Program Files\PKWARE\PKZIPW -e C:\test\" & File & " C:\test\"
        Call Shell(ShellStr, vbHide)
        File = Dir
    Loop
End Sub

用Shell去執行程式，跟用[命令字元]一樣，如果程式的路徑和參數內含有空格，就要用引號去括起來，否則空格便被誤以為是參數的分隔符。
在你的程式裏，PKZIPW的路徑上有空格，因此出現run-time error 53(即是找不到PKZIPW檔案)。 tar檔案名內也可能含有空格，因此這些檔案也無法成功。

針對這個問題，你的程式可以作以下的修改：

'用雙引號包圍字串
Function Quoted(s As String)
  Quoted = Chr(34) & s & Chr(34)    'Chr(34) 是雙引號字元
End Function

Sub ExtractAllFiles()
  Dim workDir As String: workDir = "C:\test\"
  Dim appPath As String: appPath = "C:\Program Files\PKWARE\PKZIPW"
  Dim tarFilename As String: tarFilename = Dir(workDir & "*.tar")

  While tarFilename <> ""
    Dim tarPath As String: tarPath = workDir & tarFilename
    Dim shellCmd As String: shellCmd = Quoted(appPath) & " -e " & Quoted(tarPath) & " " & Quoted(workDir)
        
    Call Shell(shellCmd, vbHide)
        
    tarFilename = Dir  
        
    DoEvents
  Wend
End Sub

另外，你的程式還有2大問題：
[問題1] 把全部解壓後的檔案放在同一個目錄內

如果來自不同tar檔的解壓檔有相同路徑和檔名，新、舊的解壓檔會產生衝突(或者會被覆蓋)。

[問題2] 用vbHide(隱藏視窗)去執行程式，而且不理執行的狀況和結果

程式不一定會解壓成功，遇到問題時，還可能停下來要用戶輸入。但是視窗被隱藏而無法得知狀況或作出回應，更糟的是程式在背後永遠佔用資源。