iT邦幫忙

1

[Windows] Apache自動監測重啟腳本 (phpStudy)

@ECHO OFF

:: 宣告屬性區域
::網址
set chkWeb=http://127.0.0.1/robots.txt
::Apache
set srvname="Apache"
::MySQLa
set srvMysql="MySQLa"
::每60秒偵測一次
set secs=60
::先啟動MySQLa,只啟動一次
::net start %srvMysql%

::說明
echo.
echo ========================================
echo ==     查詢Apache服務的狀態     ==
echo ==   每間隔%secs%秒鐘進行一次查詢   ==
echo ==   如發現其停止,則立即啟動     ==
echo ==   By Zerolocus or pratnket    ==
echo ========================================
echo.

:: 標記 start , goto專用
:start
:: 等待秒數
timeout %secs%
:: 模擬訪問 chkWeb 並產生 cache.txt
curl -o cache.txt %chkWeb%

:: EQU - 等於
:: NEQ - 不等於
:: LSS - 小於
:: LEQ - 小於或等於
:: GTR - 大於
:: GEQ - 大於或等於
:: 0 = success | 1 = errH
if %errorlevel% EQU 0 goto success
if %errorlevel% NEQ 0 goto errH

::結果 0 則寫入 Server is OK 寫進去 logs.txt 筆記本
:success
	echo %date% %time%: "Server is OK"  >> logs.txt
	goto start

:: 標記 errH , goto專用
:errH
	:: 停止Apache 服務 
	net stop %srvname%
	:: 啟動Apache 服務 
	net start %srvname%
	timeout %secs%
	echo %date% %time%: error Code:%errorlevel% >> logs.txt
	goto start

pause

個人部落格:https://pratnket.github.io/2019/02/26/windows-script/


尚未有邦友留言

立即登入留言