不確定是不是這樣，給你參考

PraseJson

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

CREATE FUNCTION [dbo].[PraseJson](@json NVARCHAR(MAX), @key NVARCHAR(1000) NULL)
RETURNS @TVP TABLE 
(
	[Key] NVARCHAR(1000),
	isType BIT,
	isList BIT,
	isTermital BIT,
	[Value] NVARCHAR(MAX)
)
AS
BEGIN
	IF @key IS NULL
		INSERT INTO @TVP
		SELECT [key] AS [Key],
		   CASE WHEN [type] >= 4 THEN 1 ELSE 0 END AS isType,
		   CASE WHEN [type] = 4 THEN 1 ELSE 0 END AS isList,
		   CASE WHEN [type] <= 3 THEN 1 ELSE 0 END AS isTermital,
		   [value] AS [Value]
		FROM OPENJSON(@json)
    ELSE
		INSERT INTO @TVP
        SELECT [key] AS [Key],
		   CASE WHEN [type] >= 4 THEN 1 ELSE 0 END AS isType,
		   CASE WHEN [type] = 4 THEN 1 ELSE 0 END AS isList,
		   CASE WHEN [type] <= 3 THEN 1 ELSE 0 END AS isTermital,
		   [value] AS [Value]
		FROM OPENJSON(@json, '$.' + @key)
	RETURN 
END

程式

DECLARE @json NVARCHAR(4000) = N'{
    "Book":{
        "IssueDate":"02-15-2019"
        , "Detail":{
            "Type":"Any Type"
            , "Author":{
                "Name":"Annie"
                , "Sex":"Female"
            }
        }
        , "Chapter":[
            {
                "Section":"1.1"
                , "Title":"Hello world."
            }
            ,
            {
                "Section":"1.2"
                , "Title":"Be happy."
            }       
        ]
        , "Sponsor":["A","B","C"]
    }
}'

SET @json = REPLACE(REPLACE(REPLACE(@json,' ',''),CHAR(10),''),CHAR(13),'')

;WITH CTE AS
(
	SELECT *
	FROM dbo.PraseJson(@json, 'Book')
	UNION ALL
	SELECT B.*
	FROM (
		SELECT * FROM CTE WHERE isTermital=0 AND isList=0
	) AS A
	CROSS APPLY dbo.PraseJson(A.[Value], NULL) AS B
)

SELECT * FROM CTE
WHERE isTermital=1

結果

   Key      isType     isList      isTermital      Value
---------|----------|----------|--------------|-------------
IssueDate	  0	          0	           1	     02-15-2019
Type	      0	          0	           1	     AnyType
Name	      0	          0	           1	     Annie
Sex	          0	          0	           1	     Female

2019/03/19 更新:

因為不知道 PraseJson 真實邏輯，所以結果不太一樣，但邏輯大概是這樣~

PraseJson

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

CREATE FUNCTION [dbo].[PraseJson](@json NVARCHAR(MAX), @key NVARCHAR(1000))
RETURNS @TVP TABLE 
(
    topKey NVARCHAR(1000),
	[Key] NVARCHAR(1000),
	isType BIT,
	isList BIT,
	isTermital BIT,
	[Value] NVARCHAR(MAX)
)
AS
BEGIN
	INSERT INTO @TVP
        SELECT @key AS topKey,
		   [key] AS [Key],
		   CASE WHEN [type] >= 4 THEN 1 ELSE 0 END AS isType,
		   CASE WHEN [type] = 4 THEN 1 ELSE 0 END AS isList,
		   CASE WHEN [type] <= 3 THEN 1 ELSE 0 END AS isTermital,
		   [value] AS [Value]
		FROM OPENJSON(@json, '$."' + @key + '"')
	RETURN 
END

程式

DECLARE @json NVARCHAR(4000) = N'{
    "Book":{
        "IssueDate":"02-15-2019"
        , "Detail":{
            "Type":"Any Type"
            , "Author":{
                "Name":"Annie"
                , "Sex":"Female"
            }
        }
        , "Chapter":[
            {
                "Section":"1.1"
                , "Title":"Hello world."
            }
            ,
            {
                "Section":"1.2"
                , "Title":"Be happy."
            }       
        ]
        , "Sponsor":["A","B","C"]
    }
}'	

SET @json = REPLACE(REPLACE(REPLACE(@json,' ',''),CHAR(10),''),CHAR(13),'')

;WITH CTE AS
(
	SELECT *
	FROM dbo.PraseJson(@json, 'Book')
	UNION ALL
	SELECT B.*
	FROM (
		SELECT * FROM CTE WHERE isTermital=0
	) AS A
	CROSS APPLY dbo.PraseJson('{"' + A.[Key] + '":' + A.[Value] + '}', A.[Key]) AS B
)

--最後執行 InsertToDB 

SELECT B.targetId
FROM (
	SELECT * FROM CTE WHERE isTermital=1
) AS A
CROSS APPLY dbo.InsertToDB() AS B

遞迴的結果

2019/03/20 更新-函數版本:

需另外新增 InsertToDB 和 Loop 函數

InsertToDB

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

CREATE FUNCTION [dbo].[InsertToDB](@key NVARCHAR(1000), @value NVARCHAR(MAX))
RETURNS NVARCHAR(1000)
AS
BEGIN
	RETURN @key + ':' + @value
END
GO

Loop

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

CREATE FUNCTION [dbo].[Loop](@json NVARCHAR(MAX), @key NVARCHAR(1000))
RETURNS @TVP TABLE 
(	
	[targetid] NVARCHAR(1000)
)
AS
BEGIN
	DECLARE @Temp TABLE
	(
		topKey NVARCHAR(1000),
		[Key] NVARCHAR(1000),
		isType BIT,
		isList BIT,
		isTermital BIT,
		[Value] NVARCHAR(MAX)
	)
	--先將JSON轉換後的結果存入@Temp
	INSERT INTO @Temp
	SELECT * FROM dbo.PraseJson(@json, @key)

	INSERT INTO @TVP
	--如果isTermital=1呼叫InsertToDB
	SELECT dbo.InsertToDB(A.[Key], A.[Value]) AS targetid
	FROM (
		SELECT * FROM @Temp WHERE isTermital=1
	) AS A
	--CROSS APPLY dbo.InsertToDB(A.[Key]) AS B --如果InsertToDB是資料表函數
	UNION ALL
	--如果isTermital=0繼續遞迴
	SELECT B.targetid AS targetid
	FROM (
		SELECT * FROM @Temp WHERE isTermital=0
	) AS A
	CROSS APPLY dbo.[Loop]('{"' + A.[Key] + '":' + A.[Value] + '}', A.[Key]) AS B

	RETURN 
END

程式

DECLARE @json NVARCHAR(4000) = N'{
    "Book":{
        "IssueDate":"02-15-2019"
        , "Detail":{
            "Type":"Any Type"
            , "Author":{
                "Name":"Annie"
                , "Sex":"Female"
            }
        }
        , "Chapter":[
            {
                "Section":"1.1"
                , "Title":"Hello world."
            }
            ,
            {
                "Section":"1.2"
                , "Title":"Be happy."
            }       
        ]
        , "Sponsor":["A","B","C"]
    }
}'	

SET @json = REPLACE(REPLACE(REPLACE(@json,' ',''),CHAR(10),''),CHAR(13),'')

SELECT * FROM dbo.[Loop](@json, 'Book')

結果

我看了你問的三個問題
其實是同一個問題
就是「把 JSON 資料存進 SQL Table」
更精確一點地說
是「把一整個 JSON 剖析成 key-value pair存進單一個 Table」

我實在想不出有什麼這麼做的必要性或實際應用的案例經驗
也可能因為如此，不會有什麼人回答這問題

不過我還是 Google 到了這篇
參考看看合不合用
dbo.JSONHierarchy

祝你好運